Events

:

:

Elektronik | Funk | Software

Der Technik-Blog

  • Social Media

    Werbung:


    New Posts


    Events

    • Keine zukünftigen Events vorhanden

    The Tech-Blog

    TTGO ESP32 OTTA LoRaWAN GPS Tracker

    LILYGO GPS LoRa | Source Code (ABP)

    Alex @ AEQ-WEB

    On this page you can find the complete sample code for the TTGO LoRaWAN GPS Tracker project. The software includes a function to evaluate the position data sent serially from the GPS module in NMEA 0183 format. Position data is automatically converted to decimal degrees (LAT, LON). ABP is used as activation for the LoRaWAN network.

    Note: The pinouts (LoRa, SPI & Serial) are defined for a specific hardware version and may have to be adapted. More information about this in the following or in the main article.

    Fields with {FILLMEIN} must be replaced by the respective keys from the LoraWAN network. This project is compatible with TTN (V2) and its successor TTS (V3) and with LoRaWAN V 1.0.3.

    Werbung:

    Versions used at testing:

    -> IDE Version: Arduino 1.8.10
    -> Library Version: Arduino LMIC (from MCCI Catena) | V. 3.2.0
    -> Hardware: LILYGO ESP32 GPS LoRa Board V1.1

    Attention: The frequency configuration (868 MHz, EU band) must be checked in the Library-Config or modified if necessary, otherwise no communication a gateway is possible in Europe! Default: 915 MHz!


    /***************************************************************************************************
       Copyright (c) 2015 Thomas Telkamp and Matthijs Kooijman
    
       Permission is hereby granted, free of charge, to anyone
       obtaining a copy of this document and accompanying files,
       to do whatever they want with them without any restriction,
       including, but not limited to, copying, modification and redistribution.
       NO WARRANTY OF ANY KIND IS PROVIDED.
    
       This uses ABP (Activation-by-personalisation), where a DevAddr and
       Session keys are preconfigured (unlike OTAA, where a DevEUI and
       application key is configured, while the DevAddr and session keys are
       assigned/generated in the over-the-air-activation procedure).
    
       Note: LoRaWAN per sub-band duty-cycle limitation is enforced (1% in
       g1, 0.1% in g2), but not the TTN fair usage policy (which is probably
       violated by this sketch when left running for longer)!
    
       To use this sketch, first register your application and device with
       the things network, to set or generate a DevAddr, NwkSKey and
       AppSKey. Each device should have their own unique values for these
       fields.
    
       Do not forget to define the radio type correctly in config.h.
    
       -------------------------------------------------------------------------------------------------
       This sample code has been adapted for LILYGO V1.1 GPS LoRa Board.
       Further information: https://www.aeq-web.com/ttgo-lilygo-esp32-gps-lora-board-lmic-abp-source-code/
    
       Note: This code example is also compatible with single channel gateways.
       Currently, only channel 0 is enabled. Further channels can be enabled in the following code below.
    
     ***************************************************************************************************/
    
    
    #include <lmic.h>
    #include <hal/hal.h>
    #include <SPI.h>
    
    #define SERIAL1_RX 34 // GPS_TX -> 34
    #define SERIAL1_TX 12 // 12 -> GPS_RX
    String read_sentence;
    uint8_t tx_payload[11];
    
    //Please change the following keys as they are given by TTN
    
    // LoRaWAN NwkSKey, network session key
    static const PROGMEM u1_t NWKSKEY[16] = { FILLMEIN };
    
    // LoRaWAN AppSKey, application session key
    static const u1_t PROGMEM APPSKEY[16] = { FILLMEIN };
    // LoRaWAN end-device address (DevAddr)
    static const u4_t DEVADDR = 0xFILLMEIN; // <-- Change this address for every node!
    
    // These callbacks are only used in over-the-air activation, so they are
    // left empty here (we cannot leave them out completely unless
    // DISABLE_JOIN is set in config.h, otherwise the linker will complain).
    void os_getArtEui (u1_t* buf) { }
    void os_getDevEui (u1_t* buf) { }
    void os_getDevKey (u1_t* buf) { }
    
    static osjob_t sendjob;
    
    // Schedule TX every this many seconds (might become longer due to duty
    // cycle limitations).
    const unsigned TX_INTERVAL = 60;
    
    //LoRa pin mapping ESP32 (LILYGO Board V1.1)
    const lmic_pinmap lmic_pins = {
      .nss = 18,
      .rxtx = LMIC_UNUSED_PIN,
      .rst = 23,
      .dio = {26, 33, 32},
    };
    
    void do_send(osjob_t* j) {
      // Check if there is not a current TX/RX job running
      if (LMIC.opmode & OP_TXRXPEND) {
        Serial.println(F("OP_TXRXPEND, not sending"));
      } else {
        // Prepare upstream data transmission at the next possible time.
    
        Serial.print("Payload: ");
        int x = 0;
        while (x < sizeof(tx_payload)) {
          printHex2(tx_payload[x]);
          Serial.print(" ");
          x++;
        }
        Serial.println();
    
        LMIC_setTxData2(1, tx_payload, sizeof(tx_payload), 0);
        Serial.println(F("Packet queued"));
      }
      // Next TX is scheduled after TX_COMPLETE event.
    }
    
    void printHex2(unsigned v) {
      v &= 0xff;
      if (v < 16)
        Serial.print('0');
      Serial.print(v, HEX);
    }
    
    void setup() {
      Serial.begin(115200);
      Serial.println("Starting");
      Serial1.begin(9600, SERIAL_8N1, SERIAL1_RX, SERIAL1_TX);
      //SPI pin mapping ESP32 (LILYGO Board V1.1)
      SPI.begin(5, 19, 27, 18);
    
    #ifdef VCC_ENABLE
      // For Pinoccio Scout boards
      pinMode(VCC_ENABLE, OUTPUT);
      digitalWrite(VCC_ENABLE, HIGH);
      delay(1000);
    #endif
    
      // LMIC init
      os_init();
      // Reset the MAC state. Session and pending data transfers will be discarded.
      LMIC_reset();
    
      // Set static session parameters. Instead of dynamically establishing a session
      // by joining the network, precomputed session parameters are be provided.
    #ifdef PROGMEM
      // On AVR, these values are stored in flash and only copied to RAM
      // once. Copy them to a temporary buffer here, LMIC_setSession will
      // copy them into a buffer of its own again.
      uint8_t appskey[sizeof(APPSKEY)];
      uint8_t nwkskey[sizeof(NWKSKEY)];
      memcpy_P(appskey, APPSKEY, sizeof(APPSKEY));
      memcpy_P(nwkskey, NWKSKEY, sizeof(NWKSKEY));
      LMIC_setSession (0x1, DEVADDR, nwkskey, appskey);
    #else
      // If not running an AVR with PROGMEM, just use the arrays directly
      LMIC_setSession (0x1, DEVADDR, NWKSKEY, APPSKEY);
    #endif
    
    #if defined(CFG_eu868)
      // Set up the channels used by the Things Network, which corresponds
      // to the defaults of most gateways. Without this, only three base
      // channels from the LoRaWAN specification are used, which certainly
      // works, so it is good for debugging, but can overload those
      // frequencies, so be sure to configure the full frequency range of
      // your network here (unless your network autoconfigures them).
      // Setting up channels should happen after LMIC_setSession, as that
      // configures the minimal channel set.
      // NA-US channels 0-71 are configured automatically
    
      LMIC_setupChannel(0, 868100000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(1, 868300000, DR_RANGE_MAP(DR_SF12, DR_SF7B), BAND_CENTI);      // g-band
      LMIC_setupChannel(2, 868500000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(3, 867100000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(4, 867300000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(5, 867500000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(6, 867700000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(7, 867900000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(8, 868800000, DR_RANGE_MAP(DR_FSK,  DR_FSK),  BAND_MILLI);      // g2-band
    
      //LMIC_disableChannel(0); //Send only at channel 0
      LMIC_disableChannel(1);
      LMIC_disableChannel(2);
      LMIC_disableChannel(3);
      LMIC_disableChannel(4);
      LMIC_disableChannel(5);
      LMIC_disableChannel(6);
      LMIC_disableChannel(7);
      LMIC_disableChannel(8);
    
      // TTN defines an additional channel at 869.525Mhz using SF9 for class B
      // devices' ping slots. LMIC does not have an easy way to define set this
      // frequency and support for class B is spotty and untested, so this
      // frequency is not configured here.
    #elif defined(CFG_us915)
      // NA-US channels 0-71 are configured automatically
      // but only one group of 8 should (a subband) should be active
      // TTN recommends the second sub band, 1 in a zero based count.
      // https://github.com/TheThingsNetwork/gateway-conf/blob/master/US-global_conf.json
      LMIC_selectSubBand(1);
    #endif
    
      // Disable link check validation
      LMIC_setLinkCheckMode(0);
    
      // TTN uses SF9 for its RX2 window.
      LMIC.dn2Dr = DR_SF9;
    
      // Set data rate and transmit power for uplink (note: txpow seems to be ignored by the library)
      LMIC_setDrTxpow(DR_SF7, 14);
    
      // Start job
      do_send(&sendjob);
    }
    
    void loop() {
      os_runloop_once();
      read_sentence = Serial1.readStringUntil(13); //13 = return (ASCII)
      read_sentence.trim();
    
      if (read_sentence.startsWith("$GPGGA")) {
        String gps_lat = sentence_sep(read_sentence, 2); //Latitude in degrees & minutes
        String gps_lon = sentence_sep(read_sentence, 4); //Longitude in degrees & minutes
        String gps_sat = sentence_sep(read_sentence, 7);
        String gps_hgt = sentence_sep(read_sentence, 9);
        String gps_lat_o = sentence_sep(read_sentence, 3);  //Orientation (N or S)
        String gps_lon_o = sentence_sep(read_sentence, 5); //Orientation (E or W)
        /*
          Serial.print("LAT: ");
          Serial.print(Latitude);
          Serial.print(" LON: ");
          Serial.print(Longitude);
          Serial.print(" ALT: ");
          Serial.print(Altitude);
          Serial.print(" SAT: ");
          Serial.println(Sat);
        */
        float Latitude = convert_gps_coord(gps_lat.toFloat(), gps_lat_o);
        float Longitude = convert_gps_coord(gps_lon.toFloat(), gps_lon_o);
        float Altitude = gps_hgt.toFloat();
        int Sat = gps_sat.toInt();
        generate_payload(Latitude, Longitude, Altitude, Sat);
      }
    }
    
    void onEvent (ev_t ev) {
      Serial.print(os_getTime());
      Serial.print(": ");
      switch (ev) {
        case EV_SCAN_TIMEOUT:
          Serial.println(F("EV_SCAN_TIMEOUT"));
          break;
        case EV_BEACON_FOUND:
          Serial.println(F("EV_BEACON_FOUND"));
          break;
        case EV_BEACON_MISSED:
          Serial.println(F("EV_BEACON_MISSED"));
          break;
        case EV_BEACON_TRACKED:
          Serial.println(F("EV_BEACON_TRACKED"));
          break;
        case EV_JOINING:
          Serial.println(F("EV_JOINING"));
          break;
        case EV_JOINED:
          Serial.println(F("EV_JOINED"));
          break;
        case EV_RFU1:
          Serial.println(F("EV_RFU1"));
          break;
        case EV_JOIN_FAILED:
          Serial.println(F("EV_JOIN_FAILED"));
          break;
        case EV_REJOIN_FAILED:
          Serial.println(F("EV_REJOIN_FAILED"));
          break;
        case EV_TXCOMPLETE:
          Serial.println(F("EV_TXCOMPLETE (includes waiting for RX windows)"));
          if (LMIC.txrxFlags & TXRX_ACK)
            Serial.println(F("Received ack"));
          if (LMIC.dataLen) {
            Serial.println(F("Received "));
            Serial.println(LMIC.dataLen);
            Serial.println(F(" bytes of payload"));
          }
          // Schedule next transmission
          os_setTimedCallback(&sendjob, os_getTime() + sec2osticks(TX_INTERVAL), do_send);
          break;
        case EV_LOST_TSYNC:
          Serial.println(F("EV_LOST_TSYNC"));
          break;
        case EV_RESET:
          Serial.println(F("EV_RESET"));
          break;
        case EV_RXCOMPLETE:
          // data received in ping slot
          Serial.println(F("EV_RXCOMPLETE"));
          break;
        case EV_LINK_DEAD:
          Serial.println(F("EV_LINK_DEAD"));
          break;
        case EV_LINK_ALIVE:
          Serial.println(F("EV_LINK_ALIVE"));
          break;
        default:
          Serial.println(F("Unknown event"));
          break;
      }
    }
    
    String sentence_sep(String input, int index) {
      int finder = 0;
      int strIndex[] = { 0, -1 };
      int maxIndex = input.length() - 1;
    
      for (int i = 0; i <= maxIndex && finder <= index; i++) {
        if (input.charAt(i) == ',' || i == maxIndex) {
          finder++;
          strIndex[0] = strIndex[1] + 1;
          strIndex[1] = (i == maxIndex) ? i + 1 : i;
        }
      }
      return finder > index ? input.substring(strIndex[0], strIndex[1]) : "";
    }
    
    float convert_gps_coord(float deg_min, String orientation) {
      double gps_min = fmod((double)deg_min, 100.0);
      int gps_deg = deg_min / 100;
      double dec_deg = gps_deg + ( gps_min / 60 );
      if (orientation == "W" || orientation == "S") {
        dec_deg = 0 - dec_deg;
      }
      return dec_deg;
    }
    
    void generate_payload(double lat, double lon, int alt, int sat) {
      uint32_t LatitudeBinary = ((lat + 90) * 1000000);
      uint32_t LongitudeBinary = ((lon + 180) * 1000000);
    
      uint8_t payload[11];
    
      payload[0] = ( LatitudeBinary >> 24 ) & 0xFF;
      payload[1] = ( LatitudeBinary >> 16 ) & 0xFF;
      payload[2] = ( LatitudeBinary >> 8 ) & 0xFF;
      payload[3] = LatitudeBinary & 0xFF;
    
      payload[4] = ( LongitudeBinary >> 24 ) & 0xFF;
      payload[5] = ( LongitudeBinary >> 16 ) & 0xFF;
      payload[6] = ( LongitudeBinary >> 8 ) & 0xFF;
      payload[7] = LongitudeBinary & 0xFF;
    
      payload[8] = ( alt >> 8 ) & 0xFF;
      payload[9] = alt & 0xFF;
    
      payload[10] = sat & 0xFF;
    
      int i = 0;
      while (i < sizeof(payload)) {
        tx_payload[i] = payload[i];
        i++;
      }
    }
    


    Info: This page was automatically translated and may contain errors
    122X122

    About the Author

    Alex, the founder of AEQ-WEB. He works for more of 10 years with different computers, microcontroller and semiconductors. In addition to hardware projects, he also develops websites, apps and software for computers.

    Top articles in this category:

    TTGO ESP32 OTTA LoRaWAN GPS Tracker

    LoRaWAN TTGO GPS Tracker

    • Video
    • DE/EN

    The second part of the LoRa GPS Tracker project is about the setup of LoRa and the registration at TTS (The Things Stack), the successor of TTN

    read more
    ESP32 LoRa Board LoRaWAN TTN ABP Connect

    ESP32 LoRaWAN Source Code (ABP)

    • DE/EN

    Source Code Example: Heltec ESP32 LoRa LoRaWAN TTN Example-Code for ABP-Mode (Arduino IDE)

    read more

    Social Media

    Werbung:


    New Posts


    Events

    • Keine zukünftigen Events vorhanden