Events

23.05.2022: Tiefpassfilter

:

Elektronik | Funk | Software

Der Technik-Blog

  • Social Media

    Werbung:


    Neue Artikel


    Events

    Der Technik-Blog

    ESP32 LoRa Board LoRaWAN TTN ABP Connect

    ESP32 LoRaWAN Source Code (ABP)

    Alex @ AEQ-WEB

    Der folgende Beispielcode basierend auf der MCCI-Library wurde für den Einstieg in das TTN LoRaWAN Netzwerk auf das ESP32 LoRa Board angepasst. Die Pins wurden für die Version 2 des Boards entsprechend definiert. Der Code ist nach Anpassung der Pin-Definitionen auch mit dem TTGO-Board sowie mit der ersten Version vom Heltec ESP32 LoRa-Board kompatibel.

    Hinweis: Dieses Codebeispiel sendet aktuell nur auf einer Frequenz und im ABP-Mode. Dadurch wird die maximale Kompatibilität mit Single Channel Gateways erreicht. Der Multi-Channel Mode sowie die Kanalanpassung können direkt im Beispielcode aktiviert werden.

    Werbung:

    Versionsinformation zum Testzeitpunkt:

    -> IDE Version: Arduino 1.8.10
    -> Library Version: Arduino LMIC (von MCCI Catena) | V. 3.2.0
    -> Hardware: Heltec ESP32 LoRa Board (V2)

    Achtung: Die Frequenzkonfiguration (868 MHz, EU-Band) muss in der Library-Config überprüft bzw. gegebenenfalls angepasst werden, da sonnst keine Kommunikation in Europa mit einem Gateway möglich ist!


    /***************************************************************************************************
       Copyright (c) 2015 Thomas Telkamp and Matthijs Kooijman
    
       Permission is hereby granted, free of charge, to anyone
       obtaining a copy of this document and accompanying files,
       to do whatever they want with them without any restriction,
       including, but not limited to, copying, modification and redistribution.
       NO WARRANTY OF ANY KIND IS PROVIDED.
    
       This uses ABP (Activation-by-personalisation), where a DevAddr and
       Session keys are preconfigured (unlike OTAA, where a DevEUI and
       application key is configured, while the DevAddr and session keys are
       assigned/generated in the over-the-air-activation procedure).
    
       Note: LoRaWAN per sub-band duty-cycle limitation is enforced (1% in
       g1, 0.1% in g2), but not the TTN fair usage policy (which is probably
       violated by this sketch when left running for longer)!
    
       To use this sketch, first register your application and device with
       the things network, to set or generate a DevAddr, NwkSKey and
       AppSKey. Each device should have their own unique values for these
       fields.
    
       Do not forget to define the radio type correctly in config.h.
    
       -------------------------------------------------------------------------------------------------
       This sample code has been adapted for Heltec ESP32 LoRa Board. 
       Further information: https://www.aeq-web.com/lorawan-ttn-mit-heltec-esp32-lora-board-abp-mode/
    
       Note: This code example is also compatible with single channel gateways. 
       Currently, only channel 0 is enabled. Further channels can be enabled in the following code below.
    
     ***************************************************************************************************/
    
    
    #include <lmic.h>
    #include <hal/hal.h>
    #include <SPI.h>
    
    //Please change the following keys as they are given by TTN
    
    // LoRaWAN NwkSKey, network session key
    static const PROGMEM u1_t NWKSKEY[16] = { 0x1D, 0x1A, 0x15, 0x1F, 0x38, 0x03, 0xC0, 0xAB, 0x7C, 0xE7, 0xAC, 0x0C, 0x4A, 0x49, 0x3B, 0x2B };
    
    // LoRaWAN AppSKey, application session key
    static const u1_t PROGMEM APPSKEY[16] = { 0xEC, 0x19, 0x87, 0xA2, 0xC7, 0x2D, 0xFC, 0x42, 0xD7, 0x35, 0xB8, 0x3B, 0xFE, 0xC0, 0x0F, 0xFE };
    // LoRaWAN end-device address (DevAddr)
    static const u4_t DEVADDR = 0x260131A3; // <-- Change this address for every node!
    
    // These callbacks are only used in over-the-air activation, so they are
    // left empty here (we cannot leave them out completely unless
    // DISABLE_JOIN is set in config.h, otherwise the linker will complain).
    void os_getArtEui (u1_t* buf) { }
    void os_getDevEui (u1_t* buf) { }
    void os_getDevKey (u1_t* buf) { }
    
    static osjob_t sendjob;
    
    // Schedule TX every this many seconds (might become longer due to duty
    // cycle limitations).
    const unsigned TX_INTERVAL = 60;
    
    // Pin mapping
    const lmic_pinmap lmic_pins = { // Pins on Heltec ESP32 LoRa Board
      .nss = 18,
      .rxtx = LMIC_UNUSED_PIN,
      .rst = 14,
      .dio = {26, 34, 35},
    };
    
    
    
    void do_send(osjob_t* j) {
      // Check if there is not a current TX/RX job running
      if (LMIC.opmode & OP_TXRXPEND) {
        Serial.println(F("OP_TXRXPEND, not sending"));
      } else {
        // Prepare upstream data transmission at the next possible time.
    
        static uint8_t payload[] = "YOUR-PAYLOAD"; //Edit your Payload
    
        LMIC_setTxData2(1, payload, sizeof(payload)-1, 0);
        Serial.println(F("Packet queued"));
      }
      // Next TX is scheduled after TX_COMPLETE event.
    }
    
    void setup() {
      Serial.begin(115200);
      SPI.begin(5, 19, 27, 18); // Pins on Heltec ESP32 LoRa Board
      Serial.println(F("Starting"));
    
    #ifdef VCC_ENABLE
      // For Pinoccio Scout boards
      pinMode(VCC_ENABLE, OUTPUT);
      digitalWrite(VCC_ENABLE, HIGH);
      delay(1000);
    #endif
    
      // LMIC init
      os_init();
      // Reset the MAC state. Session and pending data transfers will be discarded.
      LMIC_reset();
    
      // Set static session parameters. Instead of dynamically establishing a session
      // by joining the network, precomputed session parameters are be provided.
    #ifdef PROGMEM
      // On AVR, these values are stored in flash and only copied to RAM
      // once. Copy them to a temporary buffer here, LMIC_setSession will
      // copy them into a buffer of its own again.
      uint8_t appskey[sizeof(APPSKEY)];
      uint8_t nwkskey[sizeof(NWKSKEY)];
      memcpy_P(appskey, APPSKEY, sizeof(APPSKEY));
      memcpy_P(nwkskey, NWKSKEY, sizeof(NWKSKEY));
      LMIC_setSession (0x1, DEVADDR, nwkskey, appskey);
    #else
      // If not running an AVR with PROGMEM, just use the arrays directly
      LMIC_setSession (0x1, DEVADDR, NWKSKEY, APPSKEY);
    #endif
    
    #if defined(CFG_eu868)
      // Set up the channels used by the Things Network, which corresponds
      // to the defaults of most gateways. Without this, only three base
      // channels from the LoRaWAN specification are used, which certainly
      // works, so it is good for debugging, but can overload those
      // frequencies, so be sure to configure the full frequency range of
      // your network here (unless your network autoconfigures them).
      // Setting up channels should happen after LMIC_setSession, as that
      // configures the minimal channel set.
      // NA-US channels 0-71 are configured automatically
      
      LMIC_setupChannel(0, 868100000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(1, 868300000, DR_RANGE_MAP(DR_SF12, DR_SF7B), BAND_CENTI);      // g-band
      LMIC_setupChannel(2, 868500000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(3, 867100000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(4, 867300000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(5, 867500000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(6, 867700000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(7, 867900000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
      LMIC_setupChannel(8, 868800000, DR_RANGE_MAP(DR_FSK,  DR_FSK),  BAND_MILLI);      // g2-band
    
      //LMIC_disableChannel(0); //Send only at channel 0
      LMIC_disableChannel(1);
      LMIC_disableChannel(2);
      LMIC_disableChannel(3);
      LMIC_disableChannel(4);
      LMIC_disableChannel(5);
      LMIC_disableChannel(6);
      LMIC_disableChannel(7);
      LMIC_disableChannel(8);
      
      // TTN defines an additional channel at 869.525Mhz using SF9 for class B
      // devices' ping slots. LMIC does not have an easy way to define set this
      // frequency and support for class B is spotty and untested, so this
      // frequency is not configured here.
    #elif defined(CFG_us915)
      // NA-US channels 0-71 are configured automatically
      // but only one group of 8 should (a subband) should be active
      // TTN recommends the second sub band, 1 in a zero based count.
      // https://github.com/TheThingsNetwork/gateway-conf/blob/master/US-global_conf.json
      LMIC_selectSubBand(1);
    #endif
    
      // Disable link check validation
      LMIC_setLinkCheckMode(0);
    
      // TTN uses SF9 for its RX2 window.
      LMIC.dn2Dr = DR_SF9;
    
      // Set data rate and transmit power for uplink (note: txpow seems to be ignored by the library)
      LMIC_setDrTxpow(DR_SF7, 14);
    
      // Start job
      do_send(&sendjob);
    }
    
    void loop() {
      os_runloop_once();
    }
    
    void onEvent (ev_t ev) {
      Serial.print(os_getTime());
      Serial.print(": ");
      switch (ev) {
        case EV_SCAN_TIMEOUT:
          Serial.println(F("EV_SCAN_TIMEOUT"));
          break;
        case EV_BEACON_FOUND:
          Serial.println(F("EV_BEACON_FOUND"));
          break;
        case EV_BEACON_MISSED:
          Serial.println(F("EV_BEACON_MISSED"));
          break;
        case EV_BEACON_TRACKED:
          Serial.println(F("EV_BEACON_TRACKED"));
          break;
        case EV_JOINING:
          Serial.println(F("EV_JOINING"));
          break;
        case EV_JOINED:
          Serial.println(F("EV_JOINED"));
          break;
        case EV_RFU1:
          Serial.println(F("EV_RFU1"));
          break;
        case EV_JOIN_FAILED:
          Serial.println(F("EV_JOIN_FAILED"));
          break;
        case EV_REJOIN_FAILED:
          Serial.println(F("EV_REJOIN_FAILED"));
          break;
        case EV_TXCOMPLETE:
          Serial.println(F("EV_TXCOMPLETE (includes waiting for RX windows)"));
          if (LMIC.txrxFlags & TXRX_ACK)
            Serial.println(F("Received ack"));
          if (LMIC.dataLen) {
            Serial.println(F("Received "));
            Serial.println(LMIC.dataLen);
            Serial.println(F(" bytes of payload"));
          }
          // Schedule next transmission
          os_setTimedCallback(&sendjob, os_getTime() + sec2osticks(TX_INTERVAL), do_send);
          break;
        case EV_LOST_TSYNC:
          Serial.println(F("EV_LOST_TSYNC"));
          break;
        case EV_RESET:
          Serial.println(F("EV_RESET"));
          break;
        case EV_RXCOMPLETE:
          // data received in ping slot
          Serial.println(F("EV_RXCOMPLETE"));
          break;
        case EV_LINK_DEAD:
          Serial.println(F("EV_LINK_DEAD"));
          break;
        case EV_LINK_ALIVE:
          Serial.println(F("EV_LINK_ALIVE"));
          break;
        default:
          Serial.println(F("Unknown event"));
          break;
      }
    }
    


    122X122

    Über den Autor

    Alex, der Gründer von AEQ-WEB. Seit über 10 Jahren beschäftigt er sich mit Computern und elektronischen Bauteilen aller Art. Neben den Hardware-Projekten entwickelt er auch Webseiten, Apps und Software für Computer.

    Top Artikel in dieser Kategorie:

    Die besten Antennen für LoRa und der große Reichweite Test

    Die besten LoRa Antennen

    • Video

    LoRa ist eine sehr beliebte Technologie für IoT und Mikrocontroller. In diesem Artikel geht es um die besten LoRa Antennen und den großen Reichweite Test

    Weiterlesen
    Meine LoRaWAN Wetterstation nach einem Jahr

    LoRa Wetterstation 2021 Update

    • Video

    Die große LoRa Wetterstation - Zeit für ein Update von Software und Hardware. Mein Erfahrungsbericht nach einem Jahr Laufzeit.

    Weiterlesen

    Social Media

    Werbung:


    Neue Artikel


    Events